ГлавнаяСправка по использованию серверного ActionScriptКласс XML › XML.appendChild()

XML.appendChild()

my_xml.appendChild(childNode)

Прикрепляет указанный узел к списку дочерних узлов объекта XML. Этот метод оперирует непосредственно узлом, указанным в параметре childNode; узел при этом прилепляется не копированием. Если прикрепляемый узел уже существует в структуре другого дерева, прикрепление узла в новое местоположение удалит его из текущего. Если параметр childNode ссылается на узел существующий в дереве другого XML документа, прикрепленный дочерний узел помещается в новое дерево после того как будет удален из имеющегося родительского узла.

Доступно с версии

Flash Media Server 2

Параметры

childNode
Объект XMLNode, определяющий собой узел, который будет перемещен из текущего положения в список дочерних узлов объекта my_xml.

Возвращает

Булеву величину; равную true в случаи успеха; в противном случаи, false.

Пример использования

В следующем примере по порядку производятся следующие действия:

  1. Создаются два пустых XML документа, doc1 и doc2.

  2. При помощи метода createElement() создается новый узел, который затем при помощи метода appendChild() прибавляется к XML документу doc1.

  3. Показывается, как переместить узел при помощи метода appendChild() перемещая корневой узел из документа doc1 в документ doc2.

  4. Клонируется корневой узел из doc2 и прибавляется в doc1.

  5. Создается новый узел и прибавляется к корневому узлу XML документа doc1.

var doc1 = new XML(); 
var doc2 = new XML(); 
 
// Создаем корневой узел и добавляем его к doc1. 
var rootnode = doc1.createElement("root"); 
doc1.appendChild(rootnode); 
trace ("doc1: " + doc1); // Выводит: doc1: <root /> 
trace ("doc2: " + doc2); // Выводит: doc2: 
 
// Перемещаем корневой узел в  doc2. 
doc2.appendChild(rootnode); 
trace ("doc1: " + doc1); // Выводит: doc1: 
trace ("doc2: " + doc2); // Выводит: doc2: <root /> 
 
// Клонируем корневой узел и прибавляем его к doc1. 
var clone = doc2.firstChild.cloneNode(true); 
doc1.appendChild(clone); 
trace ("doc1: " + doc1); // Выводит: doc1: <root /> 
trace ("doc2: " + doc2); // Выводит: doc2: <root /> 
 
// Создаем новый узел с тем что бы прибавить его к корневому узлу (с именем clone) doc1. 
var newNode = doc1.createElement("newbie"); 
clone.appendChild(newNode); 
trace ("doc1: " + doc1); // Выводит: doc1: <root><newbie /></root>

Остальные методы и свойства

Ярлыки: , ,

  1. Пока без комментариев.
  1. Пока нету.