ГлавнаяСправка по использованию серверного ActionScriptКласс LoadVars › LoadVars.onHTTPStatus()

LoadVars.onHTTPStatus()

myLoadVars.onHTTPStatus(httpStatus){}

Срабатывает, когда Flash Media Interactive Server получает от сервера код состояния HTTP. Этот обработчик событий можно использовать для перехвата и реагирования на коды состояния HTTP.

Доступно с версии сервера

Flash Media Server 2

Параметры

httpStatus
Число; код состояния HTTP возвращаемый сервером. Например, значение 404 указывает на то, что сервер не нашел документов соответствующих запрошенному URL. Значения кодов состояния HTTP можно посмотреть в разделах 10.4 и 10.5 спецификации HTTP. (Для получения подробной информации, обратитесь к сайту W3 по адресу www.w3.org.)

Подробности

Обработчик событий onHTTPStatus() срабатывает перед onData(), который далее переключается на onLoad() со значением undefined в случаи, если загрузка дает сбой. После того как onHTTPStatus() было приведено в действие, onData() сработает всегда, независимо от того было ли переопределено onHTTPStatus(). Для более эффективного использования обработчика onHTTPStatus(), нужно написать функцию перехвата результатов вызова onHTTPStatus(); полученные результаты можно использовать далее в обработчиках onData() и onLoad(). Если onHTTPStatus() не было вызвано, это указывает на то что Flash Media Interactive Server не предпринимал попытки запросить URL.

Если Flash Media Interactive Server не может получить код статуса, или установить связь с сервером, значением по умолчанию, передаваемым коду ActionScript является 0.

Пример

Следующий пример демонстрирует как onHTTPStatus()может помочь в процессе отладки кода. В примере собираются коды статуса HTTP и их тип и значение присваиваются экземпляру объекта LoadVars.
(Заметьте что в этом примере члены экземпляра this.httpStatus и this.httpStatusType создаются на лету.)
Обработчик onData() использует эти члены экземпляра для вывода информации о HTTP ответах, которые могут быть полезны при отладке.

var myLoadVars = new LoadVars(); 
 
myLoadVars.onHTTPStatus = function(httpStatus) { 
    this.httpStatus = httpStatus; 
    if(httpStatus < 100) { 
        this.httpStatusType = "flashError"; 
    } 
    else if(httpStatus < 200) { 
        this.httpStatusType = "informational"; 
    } 
    else if(httpStatus < 300) { 
        this.httpStatusType = "successful"; 
    } 
    else if(httpStatus < 400) { 
        this.httpStatusType = "redirection"; 
    } 
    else if(httpStatus < 500) { 
        this.httpStatusType = "clientError"; 
    } 
    else if(httpStatus < 600) { 
        this.httpStatusType = "serverError"; 
    } 
} 
 
myLoadVars.onData = function(src) { 
    trace(">> " + this.httpStatusType + ": " + this.httpStatus); 
    if(src != undefined) { 
        this.decode(src); 
        this.loaded = true; 
        this.onLoad(true); 
    } 
    else { 
        this.onLoad(false); 
    } 
} 
 
myLoadVars.onLoad = function(success) {} 
 
myLoadVars.load("http://weblogs.macromedia.com/mxna/flashservices/getMostRecentPosts.cfm");

Остальные методы и свойства

Ярлыки: , ,

  1. Пока без комментариев.
  1. Пока нету.